Developing.ru

Код: Выделить всё

model tiny
org 100h

.code
push cs
pop ds
mov bx, start_m		; начальное значение M для поиска
	@loop1:
mov cx, k	
	@loop:
mov ax, bx
add ax, cx
call Calculate		; вычисляем выражение P(Ax)
call IsSostavnoe		; оно составное?
jnc @simple		; ну раз нет, значит дальше нехрена делать
loop @loop
	@simple:
or cx, cx			; цикл прервался преждевременно?
jnz @simple1		; если нет, то все значения составные
mov ax, bx
call wnum			; и их надо на экран
mov ah, 2
mov dl, ','			; и запятую еще
int 21h
	@simple1:		; ну а если прервался, значит к следующему диапазону [bx; bx+k]
inc bx
cmp bx, end_m
jnz @loop1

mov ax, 4C00h			; все сделали, с вещами на выход...
int 21h

;--------- Для подсчета значения многочлена P(ax)
;--------- На входе в AX - параметр
;--------- На выходе в AX - значение
Calculate proc near
push bx
push cx
push dx
push si
push di
push bp
pushf
mov si, offset coefs
mov cl, Level          
xor ch, ch
add si, cx
add si, cx
sub si, 2			; На последний коэф.
xor di, di			; Начальная сумма - 0
mov bx, 1			; Начальная степень AX^0
mov bp, ax		; Сохраняем пар.
	@pow:
mov ax, bx
imul word ptr [si]
add di, ax			; Умножение на коэф.
mov ax, bx
imul bp
mov bx, ax		; Переход к следующей степени параметра
sub si, 2
loop @pow
mov ax, di			; Результат в DI
popf
pop bp
pop di
pop si
pop dx
pop cx
pop bx
retn
Calculate endp

; ---------------- Составное или нет
; ---------------- На входе AX - число
; ---------------- На выходе CF=1 если составное, иначе - нет
IsSostavnoe proc near
push ax
push bx
push cx
push dx
or ax, ax
js @prost		; А если отрицательное, то хрен знает - простое или составное. Наверное простое
cmp ax, 4
jc @prost		; Меньше 4 - точно простое
mov cx, ax
mov bx, 2		; Начальный делитель для числа AX
	@div:
xor dx, dx
mov ax, cx
div bx
or dx, dx		; Проверяем остаток - если 0, значит делится нацело
jz @sost
inc bx
cmp bx, cx
jnz @div
	@prost:	; не на что кроме 1 и самого себя не делится, значит простое
clc
pop dx
pop cx
pop bx
pop ax
retn
	@sost:
stc
pop dx
pop cx
pop bx
pop ax
retn
IsSostavnoe endp

; -------- это для печати чисел
; -------- в AX - число (беззнаковое)
wnum proc far
pushf
push bx
push cx
push dx
mov bx,10
xor cx,cx
wnum_1:
xor dx,dx
div bx
push dx
inc cx
or ax,ax
jnz wnum_1
wnum_2:
pop dx
add dl,30h
mov ah,2
int 21h
loop wnum_2
pop dx
pop cx
pop bx
popf
retf
wnum endp

start_m dw 0
end_m dw 20
m dw ?
k dw 5
level db 4			; количество коэф.
coefs dw 4, 3, -7, -6		; коэфф. многочлена
end