не могу разобраться с турбо паскалем

[hellbel]

Помогите пожалуйста написать задачу в турбо паскале, а то я что-то не пойму как сделать.
Задание:
Для матрицы С [5 x 6] образовать ряд, состоящий из индексов максимальных элементов, найденных в каждой строке. В каждом столбце с номером из образованного ряда поменять местами первый и последний элементы.

[Ramzey]

Вот

Код: Выделить всё

USES Crt;
CONST
  MaxWord=65535;
TYPE
  TMatr = array [1..5,1..6] of word;
VAR
  C     : TMatr;
  Riad  : array [1..6] of byte;
  tmp   : word;
  i,j   : byte;

procedure ViewMatrix(M : TMatr);
var
  i,j : byte;
begin
  for i:=1 to 5 do
    begin
      for j:=1 to 6 do
        begin
          write(M[i][j]:8);
        end;
      writeln;
    end
end;

function GetMaxIndex(A : array of word):byte;
var
  i,MaxInd : byte;
  Max      : word;
begin
  Max:=A[0];
  MaxInd:=0;
  for i:=1 to 5 do
    begin
      if A[i]>Max then
        begin
          Max:=A[i];
          MaxInd:=i;
        end;
    end;
  GetMaxIndex:=MaxInd+1
end;

BEGIN
  clrscr;
  randomize;
  for i:=1 to 5 do
    for j:=1 to 6 do C[i][j]:=random(MaxWord);
  writeln('Ishodnaia matrica');
  ViewMatrix(C);
  writeln('Riad:');
  for i:=1 to 5 do
    begin
      Riad[i]:=GetMaxIndex(C[i]);
      writeln('i=',i,' MaxIndex=',Riad[i]);
    end;
  for i:=1 to 5 do
    begin
      tmp:=C[1,Riad[i]];
      C[1,Riad[i]]:=C[5,Riad[i]];
      C[5,Riad[i]]:=tmp;
    end;
  writeln('Konechnaia matrica');
  ViewMatrix(C);

END.