Сколько слов начинается на одну и ту же букву?

[slipknot]

народ прошу плиз помогите голову уже сломал как это сделать--->
Задание: Дана строка символов до точки. Группа символов в ней между пробелами считается словом Определить, сколько слов начинается на одну и ту же букву.

[Naeel Maqsudov]

Код: Выделить всё

const
  TermChar = '.';
  DelimiterChar = ' ';

var
  Counters:array[char] of integer;
  i,k:integer;
  s:string;
  InsideAWord:boolean;

begin
  writeln('Введите строку, завершенную точкой');
  read(s);
  i:=1;
  FillChar(Counters,SizeOf(Counters),0);
  InsideAWord:=false;
  while (i<=length(s)) and (s[i]<>TermChar) do begin
    if InsideAWord then begin
      InsideAWord:= s[i] <> DelimiterChar;
    end else begin
      if s[i]<>DelimiterChar then begin
        inc(Counters[s[i]]);
        InsideAWord:=true;
      end;
    end;
    inc(i);
  end;
  k:=0;
  for i:=0 to 255 do if Counters[char(i)]>1 then begin
    writeln('С буквы ',char(i),' начинается ',Counters[char(i)],' сл.');
    inc(k);
  end;
  if k=0 then writeln('Все слова либо начинаются с разных букв, либо слов в тексте не найдено.');
end.

[slipknot]

спасибо большое прога работает как надо!!!!!!!